欢迎来到电脑知识学习网,专业的电脑知识大全学习平台!

手机版

win7精简版img镜像-()

操作系统 发布时间:2022-11-23 13:50:27
win7精简版img镜像 ()

img文件制作

到现在懂 DOS 知识的人越来越不多了,在做 IMG 映像文件时,论坛上到处求助帮助说,这个应该这样写那个应该是怎样写,为了大家的学习,首先需要从DOS的基本学起,所以我花费一点时间来写一篇从 DOS 基础开始的详细解说到制作 IMG 映像文件的实战教程,希望大家能学到一点 DOS 知识和经验。

第一课 基本 DOS 命令集详细解说

path 指向路径命令:
path=c:\dos;c:\windows;c:\ 这条命令就是说,当我们执行一个文件时,
电脑先在当前目录下查找这个文件,找到则执行,如果没有找到,则电脑按照
path命令所指定的目录顺序去查找,先在C盘dos目录下,然后在windows目录
下,最后在C盘根目录下寻找这个文件
edit 编辑命令:
edit  w.bat回车(就是编辑 w.bat文件的意思)
ren 改名命令:
例如把abc.txt改成bne.dat,就可以输入ren abc.txt bne.dat。
type 查看命令:
我想知道abc.txt文件的内容,就从键盘上输入type abc.txt 。
diskcopy 磁盘复制命令:
diskcopy命令的格式很简单:diskcopy 源驱动器名 目的驱动器名。举个例子来
说,如果要在A驱动器上复制磁盘,就输入:diskcopy a: a: (奇怪吧,哪来两
个A盘,且看下文电脑是如何理解的)。
chkdsk 磁盘查看命令:
就输入chkdsk C:
cd 改变当前目录命令:
用法,就输入cd abc
sys 制作DOS系统盘命令:
用法,就输入sys a:
copy 拷贝文件命令:
用法,就输入copy c:\abc.txt a:\
del 删除文件命令:
用法,就输入 del c:\abc.txt
deltree 删除目录树命令:
用法,就输入 deltree c:\abc
dir 查看命令:
用法,就输入 dir 如:
用法1、dir /w
用法2、dir /p
用法3、dir /w/p
format 格式化磁盘命令:
用法1,就输入format a:(完全格式化不带任何信息)
用法2,就输入format a:/q(快速格式化不带任何信息)
用法3,就输入format a:/s(完全格式化并写入DOS启动主文件)
用法4,就输入format a:/q/s(快速格式化并写入DOS启动主文件)
md 建立目录命令:
用法,就输入md abc
mem 查看内存状况命令:
用法,就输入mem
rd 删除目录命令:
用法,就输入rd abc
cls 清屏命令:
用法,就输入cls
适用场合:屏幕上太乱了,或是屏幕上出现乱码了, 清除屏幕上显示内容但不影响
电脑内部任何信息.
move 移动文件与改目录名:
用法,就输入c:\>move c:\autoexec.bat c:\old (移动autoexec.bat文件至old目录下)
用法,就输入c:\>move c:\config.sys c:\temp (移动config.sys文件至temp目录下)
more 分屏显示命令:
用法,就输入C:\>type msdos.w40 | more
适用场合:当输出很多一屏显示不下时采用,几乎适合所有命令,尤其是type等命令
时很有用。 使用more时磁盘不能有写保护,也不适合光驱。
xcopy 拷贝目录和文件命令:
用法,就输入xcopy *.* [目录] /s
适用场合:在进行连同子目录一起拷贝时很有用,在拷贝大量文件时比COPY命令要快得多 .
attrib 设置文件属性命令:
用法1,就输入attrib +r abc.txt
用法2,就输入attrib +h *.* /s 隐含所有文件
参数:
attrib +r或-r [文件名] 设置文件属性是否为只读
attrib +h或-h [文件名] 设置文件属性是否隐含
attrib +s或-s [文件名] 设置文件属性是否为系统文件
attrib +a或-a [文件名] 设置文件属性是否为归档文件
attrib /s 设置包括子目录的文件在内的文件属性
date 显示及修改日期命令:
用法,就输入C:\>date 03-20-2005 将日期改为2005年3月20日
lable 设置卷标号命令:
用法,就输入label [盘符] [卷标名] 设定指定盘的卷标
例  子 C:\>label
     Volume in drive C is WANG
     Volume Serial Number is 2116-1DD0
     volume label (11 characters,Enter for none)?
     可以输入卷标,直接回车后
     Delete current volume label (Y/N)?
     按y删除旧卷标,按n不更改
defrag 磁盘碎片整理命令:
用法,就输入C:\>defrag
doskey 调用和建立DOS宏命令命令:
用法,就输入 doskey /reinstall      重新安装doskey
      doskey /bufsize=       设置缓冲区的大小
      doskey /macros        显示所有doskey宏
      doskey /history        显示内存中所有命令
doskey /insert|overstrike 设置新键入的字符是否覆盖旧的字
例  子]  C:\>DOSKEY
       C:\>dir
       C:\>copy C:\temp\*.* a:
       C:\>del c:\temp\*.*
       C:\>copy b:\*.* c:\temp
C:\>doskey di=dir/w/p 定义di为宏命令,意思是执行dir/w/p
fdisk 硬盘分区命令:
用法,就输入fdisk后按回车即可进入提示界面
emm386 扩展内存管理命令:
用法 lh [程序]  
将程序装入高端内存 使用此命令时,config.sys文件中需有下面两条语句。
device=emm386.exe dos=umb
lh [程序] /l:区号    将程序装入指定的umb区
lh /s          一般是由memmaker专用
例子:  C:\MOUSE\>lh mouse  将鼠标驱动程序装入高端内存
memmaker 内存优化管理命令:
用法,就输入C:\>memmaker 回车,出现提示一直回车 2. 回车继续,F3退出
msd 系统检测命令:
用法,就输入 C:\>msd 回车后可见到实例
undelete 恢复被删除的文件命令:
用法,就输入undelete
undelete /all   恢复文件且不再询问是否恢复
undelete /list  列可恢复的文件名
prompt 设置提示符命令:
适用场合:当你厌烦了c:\>的提示符或者您想使您的提示符与众不同时,您可以
试一试,非常有趣的DOS命令,可以随时显示时间与日期。
[用法] prompt $p$g 以当前目录名和>号为提示符,这是最常用的提示符
      prompt $t 表示时间      prompt $d 表示日期
        prompt $$ 表示$        prompt $q 表示=
        prompt $v 表示当前版本    prompt $l 表示<
        prompt $b 表示|        prompt $h 表示退位符
        prompt $e 表示Esc代表的字符  prompt $_ 表示回车换行
[例子] C:\DOS>prompt wang$g 将wang>作为提示符
        WANG>prompt $t$d$g  使用时间、日期和>号做为提示符
        0:01:07.77Thu 08-29-1996>prompt $p$g
        C:\DOS>
restore 恢复已备份的文件命令:
建议:如果以前用backup做过文件备份,则当原文件损坏时可以用它来恢复
文件,将用backup命令备份的磁盘中的文件恢复到另一磁盘中,备份磁盘中
应有backup.00X和control.00X这两条文件。
[用法] restore [备份盘符] [目标盘符]
        将备份盘上备份文件恢复到指定盘上
        restore /s     将备份文件包括子目录都恢复到指定盘上
        restore /p     让用户判断是否恢复文件
        restore /b:日期  恢复日期以前的文件
        restore /a:日期  恢复日期之后的文件
        restore /l:时间  恢复时间之前的文件
        restore /e:时间  恢复时间之后的文件
        restore /m     只恢复上次备份后修改过的文件
        restore /n     只恢复上次备份后已删 除的文件
        restore /d     只显示要恢复的文件名
[例子] C:\DOS>restore a: c:
        Insert backup diskette 01 in drive A:
        Press any key to continue . . .
        在A驱中放入第一张备份盘,按任意键即可,恢复完第一张后,按顺
        序放入其它盘即可。
        当您用上述命令不能正确恢复文件时请用:
        C:\DOS>restore a: c:\ /s
time 显示及修改时间命令:
用法,就输入time 即可按提示修改,不修改按回车忽略修改
set 设置环境变量命令:
用法,就输入set [环境变量]=[字符串]
例子: C:\>set path=c:\dos 与path c:\dos含义相同, 这条命令常常用在autoexec.bat中
smartdrv 设置磁盘加速器命令:
用法,它可以提高硬盘访问速度,最好在autoexec.bat文件中加载吧。
用法: smartdrv /x
     执行并驻留内存,开辟磁盘加速缓存区,并屏蔽所有驱动器缓存,是
     较常用的方法(一般用这个命令就够了)
     smartdrv /c       将缓存内的信息都写入硬盘
smartdrv /e: 数字    设置一次移动的信息量
     smartdrv /b: 数字    设置预先读取的缓冲区大小
append 设置非执行文件的路径命令:
适用场合: 当您无法在多个目录中寻找到自己输入的文稿时,可以试一试这
个命令,用法类似path。
用法: append [路径];[路径]
例子: C:\>append c:\test
     设置寻找非可执行文件路径为c:\test如果该目录下有文件1.txt时,
     在其它目录下调用1.txt找不到时,可自动寻找到c:\test目录。
     D:\UCDOS>edit 1.txt 可找到C:\test\1.txt文件
debug 程序调试命令:
如果你学过汇编语言,那你应该会使用debug,如果没学过,最好别使用.
用法  debug [文件名]
diskcomp 比较磁盘命令:
适用场合: 比较两张盘是否相同,没想到什么时候会用到,在比较用
diskcopy拷贝的两张盘,为什么不用diskcopy/v校验呢?
[用法]diskcomp [盘符1] [盘符2] 比较盘1和盘2
         diskcomp /1 只比较磁盘的第一面
         diskcomp /8 只比较没磁道的前8个扇区
[例子]C:\>diskcomp a: a:
         在同一软驱中比较两张盘
         Insert FIRST diskette in drive A:
         放入第一张盘
         Press any key to continue . . .
         Comparing 80 tracks 18 sectors per track, 2 side(s)   
         Insert SECOND diskette in drive A:
         放入第二张盘
         Press any key to continue . . . Compare OK
         比较未发现不同
         Compare another diskette (Y/N) ?n
         是否比较其它盘,选y继续比较,选n停
expand  解压工具命令:
微软公司软件原始安装盘中有许多后缀以"_"结尾的压缩文件,可以用它解压,
解除您因为少数几个文件丢失造成的麻烦。(Windows下用Winrar就可以解压)
用法,C:\>expand a:vsafe.co_ c:\dos\vsafe.com

fasthelp 快速显示帮助信息命令:
用法,在DOS下输入abc.exe /fasthelp 同/?
fc 文件比较命令:
用法,就输入fc[文件名1][文件名2]比较两文件的不同参数还有: a c l Lbn n t w nnnn
subst  路径替换命令:
用法 subst 显示当前的替代路径
        subst [盘符] [路径]                    
        将指定的路径替代盘符,该路径将作为驱动器使用
        subst /b         解除替代
[例子]C:\DOS>subst a: c:\temp 用c盘temp目录替代a盘
        C:\>subst a: /d     解除替代

第二课 基本 DOS 批处理详细解说

一、echo、@、call、pause、rem 是批处理文件最常用的几个命令,我们就从他们
开始学起
echo 表示显示此命令后的字符
echo off 表示在此语句后所有运行的命令都不显示命令行本身
@ 与echo off相象,但它是加在其它命令行的最前面,表示运行时
不显示命令行本身。
call 调用另一条批处理文件(如果直接调用别的批处理文件 ,执行完
那条文件后将无法执行当前文件后续命令)
pause 运行此句会暂停,显示 Press any key to continue... 等待用户
按任意键后继续
rem 表示此命令后的字符为解释行,不执行,只是给自己今后查找用的
二、if 、goto 、choice 、for 是批处理文件中比较高级的命令,如果这几个你用
得很熟练,你就是批处理文件的专家啦。
if 表示将判断是否符合规定的条件,从而决定执行不同的命令。 有三种格式:
1、if "参数" == "字符串"  待执行的命令
参数如果等于指定的字符串,则条件成立,运行命令,否则运行下一句。
(注意是两个等号)
如:if "%1"=="a" format a:
2、if exist 文件名  待执行的命令
如果有指定的文件,则条件成立,运行命令,否则运行下一句。
如:if exist config.sys edit config.sys
3、if errorlevel 数字  待执行的命令
如果返回码等于指定的数字,则条件成立,运行命令,否则运行下一句。
如if errorlevel 2 goto x2  DOS程序运行时都会返回一个数字给DOS,
称为错误码errorlevel或称返回码

goto 批处理文件运行到这里将跳到goto 所指定的标号处,一般与 if 配合使用。
如:
goto end
:end
echo this is the end
: 这是标号字符(所在位是冒号),是用来执行被 goto 跳转所用的标号字符,
标号所在行是不会被执行,如:
:end 等等...

choice 使用此命令可以让用户输入一个字符,从而运行不同的命令。使用时应该
加/c:参数,c:后应写提示可输入的字符,之间无空格。它的返回码为1234……
如: choice /c:dme defrag,mem,end
将显示
defrag,mem,end[D,M,E]?
例如,test.bat的内容如下:
@echo off
choice /c:dme defrag,mem,end
if errorlevel 3 goto defrag 应先判断数值最高的错误码
if errorlevel 2 goto mem
if errotlevel 1 goto end
:defrag
c:\dos\defrag
goto end
:mem
mem
goto end
:end
echo good bye
此文件运行后,将显示 defrag,mem,end[D,M,E]? 用户可选择d m e ,
然后if语句将作出判断,d表示执行标号为defrag的程序段,m表示执行
标号为mem的程序段,e表示执行标号为end的程序段,每个程序段最后都
以goto end将程序跳到end标号处,然后程序将显示good bye,文件结束。

for 循环命令,只要条件符合,它将多次执行同一命令。
格式FOR [%%f] in (集合) DO [命令]
只要参数f在指定的集合内,则条件成立,执行命令
如果一条批处理文件中有一行:
for %%c in (*.bat *.txt) do type %%c
含义是如果是以bat或txt结尾的文件,则显示文件的内容。
device和devicehigh
加载一些内存驻留程序,用于管理设备。比如内存管理程序和
光驱驱动程序等。
如: device=c:\dos\himem.sys
device=c:\dos\emm386.exe ram
devicehigh=c:\cdrom\cdrom.sys

himem.sys和emm386.exe
DOS只能直接使用640K的内存,即基本内存,必须依靠其它内存管理程序来
使用更多的内存,这两条命令就是最常用的内存管理程序。
himem.sys 负责管理扩展内存。
emm386.exe 负责管理高端内存并在扩展内存中模拟扩充内存供某些软件使用。
为了使用更多的内存,配置文件中应有:
device=c:\dos\himem.sys
device=c:\dos\emm386.exe ram
注意:EMM386.exe 要求先安装 himem.sys,因而必须确保
安装 himem.sys 的配置命令在 emm386.exe 之前。
dos=high,umb 这两个参数也可以分开写成两条语句,即:
dos=high
dos=umb
应在config.sys中加入这条命令,这样会将DOS的系统文件移入高端
内存,空出更多的基本内存给其它软件使用。 注意,如果用户没有
安装emm386.exe,umb这个参数是没有实际意义的
lastdriver lastdriver 规定用户可以访问的最大驱动器符数目,也就是DOS所能
识别的最后的驱动器符(字母)。如果设定的驱动器符数目小于本机上
的实际驱动器数,则此lastdriver命令会被忽略掉。缺省的最大驱动
器符数目为本机的实际驱动器数目加一。
:: 二个冒号,它和批处理文件中的 rem 含义相同,即注释
ramdrive.sys 虚拟磁盘文件。
只要在 config.sys 中加入 device=ramdrive.sys 就可使用虚拟磁盘了
比如:
   device=c:\dos\ramdrive.sys 1024 /e
表示在扩展内存中建立 1M 的虚拟磁盘。如果加/a参数,则表示在扩充
内存中建立虚拟磁盘。
%CDROM% %CDROM%是光驱盘符的变量字符串,用它可以把所在的任意光驱盘符替为
真实盘符, 需要与光驱驱动模块一同执行,如:
LH \MSCDEX.EXE /D:mscd001 /L:%CDROM%
%RAMD% %RAMD%是随机虚拟磁盘, 此盘创建在扩展内存中, 建立此盘的模块就是
ramdrive.sys ,见上面的“虚拟磁盘文件”说明。
另外这个虚拟内在还有更强大的虚拟内存管理器,可以超过64MB的内存
管理,就是 XMSDSK.EXE 与 EMSDSK.EXE,

第三课 《Windows 98 启动盘的详细解说》

在这篇里解说的是 Windows 98 启动盘的工作原理和特征及功能,也对每个文件作了详细说明,你就能够明白 Windows 98 启动盘的工作原理了, 自己就能修改 Windows 98 启动盘来改制自己所需要用的功能了, 这篇就写到这里。
在开始前选讲一下 Windows 98 启动盘的特征和功能,现已对 Windows 98 的
启动盘作了很大的更改。下列各项是针对 Windows98 的新增特性。
- 多配置启动菜单
- 实模式 CD-ROM 支持
- EBD.CAB 文件
- RAMDRIVE
- WINDOWS98 启动问题
- 使用启动盘上的工具
多配置启动菜单
==============
如果用新的 Windows98 启动盘启动计算机,那么,系统将显示引导菜单,用于
加载常用CD-ROM 驱动器或执行正常的干净引导。进行选择之后,Config.sys
文件就加载对应的 CD-ROM 驱动程序(如果已经选定),然后加载 2MB RAMDrive。
RAMDrive 存储解决常见问题所必须的诊断工具。
要注意是:
RAMdrive 可能导致 CD-ROM 的驱动器号向后顺延一个字母。如果 CD-ROM 常为
驱动器 D:,现在可能就变为驱动器 E:。
实模式 CD-ROM 驱动程序
=====================
Windows 98 启动盘中含有常规的 ATAPI IDE 和 SCSI CD-ROM 驱动程序,
使用此驱动程序,即使 Windows98 GUI 不可用,CD-ROM 也可在 DOS 中
正常工作。
注意,并不支持所有 CD-ROM 驱动器。如果使用这些驱动程序时,CD-ROM
驱动器无法正常工作,那么,就必须使用 CD-ROM 驱动器所附带的驱动程序。
Windows 98 启动盘里面共有文件 24 个, 下面先把这 24 个文件
的功能和作用作个详细说明。启动盘的文件如下:
=================================================================
文件 功能
Aspi2dos.sys 实模式的 Adaptec CD-ROM 驱动程序
Aspi4dos.sys 实模式的 Adaptec CD-ROM 驱动程序
Aspi8dos.sys 实模式的 Adaptec CD-ROM 驱动程序
Aspi8u2.sys 实模式的 Adaptec CD-ROM 驱动程序
Aspicd.sys 实模式的 Adaptec CD-ROM 驱动程序
Autoexec.bat 启动批处理文件(也就是我们常要修改的文件,在启动时用到的
第五个文件,一般来说也就是最后一个启动时用到的文件,当它
执行完后,基本完成了操作,计算机就等待着你执行以后程序或
命令了)
Btcdrom.sys Mylex/BusLogic CD-ROM 驱动程序
Btdosm.sys Mylex/BusLogic CD-ROM 驱动程序
Command.com DOS 命令解释程序(在启动时用到的第四个文件)
Config.sys 加载设备驱动程序(这个也是我们常要修改的文件,很重要的一个,
在启动时用到的第三个文件)
Drvspace.bin Microsoft 磁盘空间管理压缩驱动程序
Ebd.cab 包含解压缩实用程序的 Cab 文件
Ebd.sys EBD 标识的文件
Extract.exe 解压 Ebd.cab 文件的文件
Fdisk.exe 磁盘分区工具
Findramd.exe 启动过程中查找 RAMDrive 的实用程序
Flashpt.sys Mylex/BusLogic CD-ROM 驱动程序
Himem.sys XMS 内存管理程序
Io.sys 系统引导文件(在启动时第一个用到的文件)
Msdos.sys 引导选项信息、路径、多层引导等等(在启动时第二个用到的文件)
Oakcdrom.sys ATAPI CD-ROM 驱动器的通用设备驱动程序
Ramdrive.sys 启动时创建 Ramdrive (也就是这个变量符 %RAMD% 是随机虚拟磁盘)
Setramd.bat 搜索第一个可用作 Ramdrive 的虚拟磁盘驱动器

下面是 Windows 98 启动盘里的 EBD.CAB 文件
===========================================
Ebd.cab 文件是一个压缩文件,在启动时,其内容被解压缩释放至 Ramdrive
虚拟磁盘下,也就是仿真物理硬盘。下面顺便先讲说一下这个 Ramdrive 的创建。
创建 RAMDrive 虚拟磁盘即仿真物理硬盘
======================================
RAMDrive 是在处理 Config.sys 文件的过程中予以创建的,其大小为 2MB。
Ramdrive 是用系统 RAM 创建的,用以仿真物理硬盘。如果不创建 RAMdrive 虚拟
硬盘(仿真物理硬盘),在单张 1.44 MB 的软盘上就没有足够的空间存放诊断工具
以及 CD-ROM 驱动程序。
警告:
由于 RAMDrive 是在处理 Config.sys 文件的过程中用由系统 RAM 予以创建的,
因此,它只临时存在。如果正常重启动计算机,它将消失。
下面列出了 Ebd.cab 文件中所包含的文件及功能。
================================================
文件 功能
Attrib.exe 添加或删除文件属性
Chkdsk.exe 小而简单的磁盘状态工具
Debug.exe 调试实用程序
Edit.com 实模式的紧急文本编辑器
Ext.exe 新的简单文件提取实用程序
Format.com 磁盘格式化工具
Mscdex.exe 用于 MS-DOS 的 Microsoft CD-ROM 文件扩展
Scandisk.exe 磁盘状态工具
Scandisk.ini 磁盘状态工具配置文件
Sys.com 传输系统文件,将磁盘制成启动盘
好了,到此我们已经讲了 Windows98 启动盘的各个文件的用途和作用,下面开始
讲解我们常要修改的二个文件了,
1、Windows98 启动盘启动的过程如下:
启动过程:开机后从→IO.SYS→MSDOS.SYS→CONFIG.SYS→COMMAND.COM→AUTOEXEC.BAT
一般来说我们需要修改的是 CONFIG.SYS 和 AUTOEXEC.BAT 而涉及到启动光盘制作的则
主要就是这二个 CONFIG.SYS 和 AUTOEXEC.BAT 文件。
2、CONFIG.SYS 文件内的详细讲解
========================================================================
[menu] 这是启动时显示的菜单选顶
menuitem=CD, Start computer with CD-ROM support. 选择这项后启动时带光驱支持
menuitem=NOCD, Start computer without CD-ROM support. 选择这项后启动时不带光驱支持
menuitem=HELP, View the Help file. 选择这项启动后进入查看帮助文件
menudefault=CD,30 这项是显示等待进入的时间,默认为30秒,可以自己设定。
menucolor=7,0 这项是屏幕显示颜色,默认是黑底白字。详细如下:
0= 黑色 1=蓝色 2=绿色 3=青色 4=红色 5=红紫色 6=棕色 7=白色 8=灰色
9=淡蓝色 10=淡绿色 11=淡青色 12=淡红色 13=淡红紫色 14=黄色 15=淡白色
[CD] 这个标签是当菜单选项选择了 CD 标签就对应着执行这项
device=himem.sys /testmem:off 这项是 XMS 内存管理程序
device=oakcdrom.sys /D:mscd001 这项是 ATAPI CD-ROM 驱动器的通用设备驱动程序
device=btdosm.sys 这项是 Mylex/BusLogic CD-ROM 驱动程序
device=flashpt.sys 这项是 Mylex/BusLogic CD-ROM 驱动程序
device=btcdrom.sys /D:mscd001 这项是 Mylex/BusLogic CD-ROM 驱动程序
device=aspi2dos.sys 这项是 实模式的 Adaptec CD-ROM 驱动程序
device=aspi8dos.sys 这项是 实模式的 Adaptec CD-ROM 驱动程序
device=aspi4dos.sys 这项是 实模式的 Adaptec CD-ROM 驱动程序
device=aspi8u2.sys 这项是 实模式的 Adaptec CD-ROM 驱动程序
device=aspicd.sys /D:mscd001 这项是 实模式的 Adaptec CD-ROM 驱动程序
[NOCD] 这个标签是当菜单选项选择了 NOCD 标签就对应着执行这项
device=himem.sys /testmem:off 这项是 XMS 内存管理程序
[HELP] 这个标签是当菜单选项选择了 HELP 标签就对应着执行这项
device=himem.sys /testmem:off 这项是 XMS 内存管理程序
[COMMON] 这个是公用标签
files=10 这项是允许同时打开的文件个数,默认是10个文件,一般不要超过 30 个文件
buffers=10 这项是设置系统的磁盘缓存块数,默认是10块数,一般不要超过 30 个文件
dos=high,umb 这项是把 DOS 载入到高端内存
stacks=9,256 这项是设置DOS堆栈的个数
devicehigh=ramdrive.sys /E 2048 这项是设置虚拟盘即仿真物理硬盘并设置大小为2MB
lastdrive=z 这项是设置最后盘符为 Z ,也就是说最大不能超过这个值
3、AUTOEXEC.ABT 文件内的详细讲解
======================================================
@ECHO OFF 这项是不显示 DOS 屏幕提示
set EXPAND=YES 这项是设置解压为自动,也就是 EBD 的解压
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
以上三条是设置虚拟内存的参数
cls 这是清屏命令
call setramd.bat %LglDrv% 这项是调用 setramd.bat 文件并设置虚拟磁盘的内存
set temp=c:\ 这项是设置临时文件夹路径为 C 盘
set tmp=c:\ 这项是设置临时文件夹路径为 C 盘
path=%RAMD%:\;a:\;%CDROM%:\ 这项是设置系统环境变量,在DOS下就不用来回切换盘符了
copy command.com %RAMD%:\ > NUL 这项是复制 command.com 到虚拟盘中
>NUL 是在屏幕上不显示执行后的结果
set comspec=%RAMD%:\command.com 这项是设置 DOS 命令解释器的路径为 %RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL 这项是复制 extract.exe 到虚拟盘中 >NUL 同上
copy readme.txt %RAMD%:\ > NUL 这项是复制 readme.txt 到虚拟盘中 >NUL 同上
:ERROR 这项是错误的提示标签
IF EXIST ebd.cab GOTO EXT 这项是如果 ebd.cab 文件存在就跳转到 EXT 标签
echo Please insert Windows 98 Startup Disk 2 这项是如果 ebd.cab 文件不存在
屏幕上就将显示“请插入 Windows 98 启动盘 2”
echo. 这项是空一行
pause 这是项是执行到这里时就暂停,屏幕上就显示“Press any key to continue...”
意思是按任意键继续...
GOTO ERROR 这项是跳转到 ERROR 标签
:EXT 这项是被跳转过来的标签,(就是这项 IF EXIST ebd.cab GOTO EXT)
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
在虚拟内存中执行 extract.exe,把 ebd.cab 里面的文件解压到虚拟盘中
echo The diagnostic tools were successfully loaded to drive %RAMD%.
这行是在屏幕上提示“诊断工具已经成功的载入内存"X"”X是你虚拟内存的盘符中
echo. 空一行
IF "%config%"=="NOCD" GOTO QUIT 如果你在 config.sys 标签中选择 NOCD 转到 QUIT 标签
IF "%config%"=="HELP" GOTO HELP 如果你在 config.sys 标签中选择 HELP 转到 HELP 标签
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM% 这项是加载光驱命令并自动分配一个光盘符
echo. 空一行
GOTO QUIT 跳转到 QUIT 标签
:HELP 这项是帮助标签,是在 config.sys 标签中选择 HELP 转到这里的标签
cls 清屏命令
call help.bat 这项是调用帮助文件的命令
echo Your computer will now restart and the startup menu will appear.
这条是,当 HELP.BAT 这条命令执行完后屏幕上就显示“你的计算机现在将重新启动”
echo. 空一行,以下均是空一行
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
restart.com 这个就是重新启动计算机的执行程序
GOTO QUIT 这项是跳转到 QUIT 标签
:QUIT 这项是跳转标签, 是由上面跳转过来的
echo To get help, type HELP and press ENTER.
这项是屏幕上提示你,输入“help”后回车来查看帮助文件。
echo. 空一行
rem clean up environment variables 这项是清理所有上面设置过的环境变量
set CDROM= 这项是设置 CDROM 为盘符, 由变量而定
set LglDrv= 这项是设置虚拟磁盘为盘符, 由变量而定
特别注意要点:
config.sys 里的 menuitem=CD 和 下面 [CD] 还有 autoexec.bat 里的 [CD] 一定
要保持一致,否则系统会找不到该执行的程序。依此类推....
device=oakcdrom.sys /D:mscd001 光驱驱动 命名为“mscd001”
光驱的名字也要和 autoexec.bat 里面的保持一致,目的和上面一样
下面还有 Windows 98 启动问题讲说一下
=====================================================================
本节包含部分常用的疑难解答步骤,在需要使用 Windows98 启动盘时,就可
以按此步骤进行操作。这些步骤至少可将用户引导到“安全模式”,这样就可
获取 Windows98 的扩展“帮助”系统以进一步解答所遇到的问题。

以安全模式启动计算机
--------------------
Windows 98 启动失败的原因很多。检测故障的第一步,是尝试以安全模式启动计算机。
若安全模式能正常工作,则可以使用位于“开始”菜单/“帮助”选项中的扩展“帮
助”系统和疑难解答。
>>>以安全模式启动计算机:
1. 取出启动盘,重新启动计算机。计算机重新启动之后,在 Windows 开始装载前请按
住 CTRL 键,直到显示“Windows 98 Startup Menu”。(如果运行的是 Windows 95,
在出现“启动 Windows 95”提示时请按 F8。)
2. 选择“Startup”菜单上的“Safe Mode”。
如果能以“安全模式”启动计算机,请用 Windows 98 的“帮助”解决存在的问题。

安装失败和计算机不启动
----------------------
Windows 98 安装不能成功完全的常见原因有多种。下面的章节将解释如何克服这些问
题。关于其他安装问题的更详细信息,请参阅 Windows 98 光盘或第一张安装软盘上
Win98 文件夹中的 Setup.txt 文件。
在运行安装程序时如果遇到以下错误消息:
* 非法系统盘
* MS-DOS 版本不对
* Command.com 文件丢失或损坏
* 压缩驱动程序错误
这很可能是计算机的启动驱动器需要更新系统文件。可用 SYS 命令将需要的文件复制
到计算机上。
注意:如果您正在装入压缩软件,则需要知道您的主驱动器代号。一般为 H。如果没有装
入任何压缩软件,则需使用 SYS 命令将系统文件传入 C 驱动器。
>>>使用 SYS 命令将系统文件复制到计算机上:
1. 用 Windows 98 启动盘重新启动计算机,在启动菜单上选择选项 2,然后按 ENTER。
2. 在 A:\ 提示符后面键入:SYS X: (其中 X 为主或启动驱动器)。
3. 如果上述过程成功,则显示“System transferred”消息。如果不成功,请检查键
入的主驱动器号是否正确。
要点:如果已经安装了硬盘所附带的软件,请仔细阅读文档,以了解用软盘启动计算机
的详细方法。

反病毒软件
----------
如在安装期间仍在运行反病毒软件,那么,它们可能阻碍安装程序更新系统文件。若果
真如此,请禁用或卸载反病毒软件,然后再运行安装程序。
注意:有些计算机内置有反病毒软件。在运行安装程序之前也应当禁用这些内置的反病
毒软件。如果不禁用它们,可能会收到警告消息,通知您主引导记录已被更改。如果接
收到此类消息,就必须接受这些更改,否则安装程序可能停止响应。

在检测硬件时安装程序停止响应
----------------------------
如果在检测硬件时安装程序停止响应,请关闭计算机稍等数秒钟,然后再开机。可能需
要如此反复多次,因为安装程序在多种不同的检测模式中可能停止响应。
注意:关闭计算机的电源。不要用复位按钮或 CTRL+ALT+DELETE 重新启动计算机。
如果安装仍然不能顺利进行,可能需要以安全模式启动计算机,以便查阅与硬件检测有
关的帮助主题。

压缩的驱动器未连接
------------------
不能访问压缩驱动器的原因很多。如果 Windows 目录在一个尚未连接的驱动器上,则
无法启动 Windows。如果怀疑压缩驱动器有问题,请试用磁盘扫描程序来修复。
在 A:\ 提示符后面键入:
Scandisk /Mount X:
其中 X 为压缩驱动器号。磁盘扫描程序将会修复此磁盘并连接该驱动器。
如果没有足够的内存来检查压缩的磁盘,请参阅第一张安装软盘或 Windows
98 光盘中 Setup.txt 文件的“从 MS-DOS 安装 Windows 98”一节。

使用启动盘上的工具
==================
本节介绍 Windows 98 启动盘上所附带的实用程序。运行这些工具的步骤如下:
1. 将 Windows 98 启动盘插入软盘驱动器,然后重新启动计算机。
2. 在启动菜单上选择选项 1 或 2(取决于您是否要访问CD-ROM),然后按 ENTER。
3. 在 MS-DOS 命令提示符 (A:\) 后面键入要运行的实用程序名称,然后按 ENTER。

SCANDISK.EXE 和 CHKDSK.EXE
----------------------------
这两个程序常用于检查硬盘错误。如果您怀疑硬盘上有文件毁坏或存在其他问题,请运
行磁盘扫描程序来检查并修复硬盘。
要检查所有硬盘错误,请键入:
Scandisk /all
要扫描硬盘的所有表面,最大限度防止数据丢失,请键入:
Scandisk /all /Surface
注意:
您可能会收到关于长文件名的错误消息。MS-DOS 版本的磁盘扫描程序对于长文件名方
面的问题,只能检测而无法纠正。要纠正此类错误,必须在 Windows 98 中运行磁盘扫
描程序。
如果您有压缩磁盘,可能会收到“没有足够的内存来检查压缩磁盘”的消息。解决这个
问题的方法是:按照在本节前面的步骤 1 中介绍的方法,用 Windows 98 启动盘来启
动计算机。选择选项 2。这样便有足够的内存,令磁盘扫描程序检查压缩的硬盘。
如果磁盘扫描程序不能检查您的驱动器,请用 CHKDSK.EXE 试一试。CHKDSK 可以检查
链接的文件和丢失的单元。

SYS.COM
=======
SYS 命令用于在盘与盘之间复制系统文件。这些系统文件是计算机启动时必需的。
>>>向 C 盘传输系统,请键入:
SYS C:
然后按 ENTER。稍侯几秒钟,将出现“System transferred”消息。
执行 SYS 的结果,下述文件被复制到盘中:
* IO.SYS
* MSDOS.SYS
* COMMAND.COM
如果 SYS C: 命令未工作,而且 C 盘为压缩盘,则需要键入主驱动器名。如果使用
DblSpace 或 DrvSpace 程序,通常主驱动器为 H 盘。如果您不知道该驱动器的号,
请运行 ScanDisk 并等待观察有没有关于压缩磁盘的提示。

FDISK.EXE 和 FORMAT.EXE
------------------------
FDISK 和 FORMAT 实用程序是在机器中安装新盘或清理旧盘时必需的。先用 FDISK 创
建分区,然后再用 FORMAT 格式化该分区以便使用。
警告: 使用 FDISK 不当可能会毁掉硬盘上的所有数据。如果不会使用 FDISK,先查阅
计算机文档。
可以用 Windows 98 版本的 FDISK,在 512 兆以上的盘上创建 FAT32 分区。FAT32 减
少了较大驱动器上的簇的大小,并允许在 2 GB 以上的硬盘上创建单一的分区。
要查看当前驱动器的状态,请在 MS-DOS 命令提示符后面键入: FDISK /STATUS。
用 FDISK 对磁盘分区之后,便该使用 FORMAT 命令。要格式化最新分区的驱动器,
请键入:
FORMAT X:
其中 X 为要格式化的驱动器。
要格式化 C 盘,必须将此盘格式化为系统盘,才能用它启动计算机,请在 FORMAT 命
令后面键入 /s:
FORMAT C: /s
在该驱动器格式化之后,将自动复制系统启动文件。

CD-ROM 驱动器
--------------
Windows 98 启动盘包含一组通用的 CD-ROM 驱动程序。这些驱动程序可用于大多数
IDE ATAPI 和 SCSI CD-ROM 模式。
如果个别 CD-ROM 驱动器不能使用这些驱动程序,则需要使用 CD-ROM 驱动器所附带的
驱动程序。
下面是关于 CD-ROM 驱动程序的已知问题:
1. 和声卡连接的 CD-ROM 驱动器不能正常工作。
2. 早期的 CD-ROM 驱动器(例如 Mitsumi、Panasonic 和 Sony)可能不能使用这些
驱动程序。一些老的 IDE 控制器同样不能使用。
3. 启动盘上的 SCSI 驱动程序支持大多数 Adaptec、Buslogic 和 Mylex 适配器。有
些其他 SCSI CD-ROM 驱动器可能无法使用启动盘上的驱动程序。
4. 如果 SCSI 控制器被配置为非默认的 I/O 区域,则驱动程序可能不检测您的 SCSI
卡。有关该卡的默认 I/O 区域,请参阅 SCSI 驱动程序文档。
5. 不含许多 PC 卡 (PCMCIA) CD-ROM 驱动器的驱动程序。

EXT.EXE
-------
EXT 命令与 Extract.exe 实用程序连用,很容易将 Windows 98 文件摘取到硬盘。可
以用它恢复丢失或毁坏的文件。
如果在安装时遇到“文件丢失”或“执行文件错误(如一般保护错误)”或“非法页面
错误”的消息,则这个实用程序特别有用。
>>>用 Ext.exe 摘取文件的步骤:
1. 使用 Windows 98 启动盘重新启动计算机,选择选项 1,然后按 ENTER。
2. 将 Windows 98 光盘插入驱动器。
3. 在 MS-DOS 命令提示符后面键入 EXT,然后按 ENTER。
4. 在提示后面输入 Windows 98 安装文件的位置、要抽取的文件位置和安放所抽取文
件位置。

注意:
如果 CD-ROM 驱动器号为 E,则安装文件的位置为 E:\WIN98。
如果想一次摘取多个文件,可以使用通配符。

第四课《启动盘实战系列一, 全自动安装 Windows 98》

在这篇里解说的是全自动安装 Windows 98 , 其实做这个启动盘也不难的, 只要为 Windows 98 做一个安装用的应答配置文件就能实现全自动了, 利用 EasyBoot自带的 setup98.img 启动映像来改制自己的 Windows 98 全自动安装盘, 所需的工具这要一个 Winimage 就行了

一、利用 EasyBoot自带的 setup98.img 启动映像来改制自己的 Windows 98 全自动安装盘,
这个文件我们已经有了,还要的就是做自动应答文件的工具了,这个工具在 Windows 98 安装
盘里,我还记得我第一次安装 Windows 98 时候那种激动的心情,因为第一次还不懂安装,在
安装过程中看着精美的画面,伴随着功能介绍,又顺利的安装着,这过程简直就是一种享受。
随着Windows 的不断更新,在里面安装的软件越多,系统也是越不稳定,重装 Windowns 就成
了家常便饭。重复的事情做多了就觉得烦,在这个时候就还谈上享受罗,只有折磨才对了。
Windows 98 全自动的配置过程
  选介绍一下 MS Batch 98 是一个可以让 Windows 98 自动安装的工具,使用 MS Batch 98
可以轻松地创建自动执行“Windows 98 安装程序”的脚本(.INF文件)。在安装 Windows 98
时,只要调用这个脚本文件,那么在安装程序将不在有提示信息,而是完全自动安装。同时,它
还可以使用立即获取功能搜索本地的注册表,轻松创建脚本文件,供你下次重装系统时使用。
   首先你要安装 MS Batch 98,其安装文件在 Windows 98 安装盘中。
此软件在 Windows 98 的完整安装盘中的路径为 *:\Tools\Reskit\Batch。如图1

可以双击 Setup.exe 将其安装到硬盘上,再通过选“开始→程序→Microsoft Batch 98”来
运行它;也可以在安装目录中直接双击 Batch.exe 运行它。
该软件运行后主界面如图2。

运行后,其界面如上图。单击主界面上的“一般安装选项”、“网络选项”、“可选的组件”、
“Internet Explorer选项”、"高级选项"按钮可进行相应的设置。其中所包含的设置非常丰富,从
产品序列号、用户名称、Windows 98安装目录到IE 4.0浏览器的起始页,还有是否安装哪些网络协
议。对于一般用户来说“一般安装选项”和“可选的组件”按钮最为常用。设置好有关选项后,单
击“保存设置到INF”按钮,程序将提示保存的路径与文件名,输入后单击"确定"按钮。如果你要修
改已有的脚本文件,只需选择菜单"文件"中的"打开",选择脚本文件所在的位置,然后主界面的相
关栏目修改即可。
   使用脚本文件也很简单,在 DOS 命令提示符下按照“setup 脚本文件名”即可完成自动安装。
例如:setup *:\batch.inf。在使用时需要注意,必须指定脚本文件的完整路径,否则,安装程序
将由于错误而终止(* 号代表所在盘符)。
   如果你已经安装了 Windows 98 系统,可以通过注册表中的内容自动创建脚本文件。具体操作
是,单击"现在收集"按钮,然后在相应栏目做适当修改保存即可。
例子就是这样,单击“现在收集”则可将本机上次安装 Windows 98 的相关设置读为默认值,
之后可再根据自己的实际情况修改;如欲进行全新的设置,则跳过此步。
在“一般安装选项”中可输入(或选择)产品序列号、默认安装目录、用户信息和计算机信息、地
区设置及其他一些安装提示。
在“网络选项”中可设置本机安装的协议、网络属性等。 也可不改!
在“可选的组件”中可修改附件或桌面主题的内容等。 也可不改!
在“Internet Explorer选项”中可修改Internet选项的值。 也可不改!
在“高级选项”中为在线升级等信息的设置。 也可不改!
单击“保存设置到 INF”即可将相关设置保存为安装脚本文件(XXX.inf),如保存为 *:\Autobatch.inf。

   最后要说明的是,该版本的 Batch.exe 是使用 Win95 公用控件的32位应用程序,所以该程序只
能在 Windows 98 下运行。并且 Windows NT 也不支持注册表的自动检查。另外 MS Batch 98 有详细
的中文帮助文件,有什么疑问可以到里面去查询。
   同样 Windows ME 也可以使用这个文件进行安装。
二、下面是 Windows 98 的安装参数
setup 所有命令行参数的使用及语法的有关帮助,有可能也不完全哦。
/C
不安装Smartdrive磁盘缓存。
/D
忽略现有版本Windows的初始设置。如果用户是在Windows系统文件缺少或损坏时重新安装Windows时可使用该参数。
/DOMAIN: domain_name
设置Microsoft网络用户的Windows
NT的合法登录域名为domain_name。
/F
忽略在文件名的本地缓存中寻找文件。这样虽然安装时间稍长,但却
占用极少的内存。
/IA
不运行Setup.inf文件中的[AfterProvider]节(这个最常用)。
/IB
不运行Setup.inf文件中的[BeforeProvider]节。
/IC
如果使用该参数并未设置RMDrivers=1,则启动时不运行Config.sys/
Autoexec.bat文件。
/ID
忽略检查安装Windows98所需的最小磁盘空间。
/IE
不创建启动盘。如使用此参数,则相应也不创建windowscommandebd文
件夹。
/IF
快速安装。
/IG
允许在一些含较早版本BIOS的Gateway和Micro计算机上运行Setup。
/IH
在显着位置运行Scandisk。使用该参数有利于用户在运行Scandisk过
程中或发生错误时清楚了解运行结果。
/IL
安装Logitech鼠标驱动。如果用户使用的是Logitech Series C鼠标,
可使用该参数。
/IM
忽略对低位常规内存的检查 (这个最常用)
/IN
不执行网络安装程序。跳过网络软件和网络设置画面显示。
/IQ
不检查交叉链接文件。
/IR
不更新主引导纪录(MBR)。
/IS
不运行 Scandisk (也就是磁盘检测,这个最常用)。
/IV
Windows 升级安装时跳过显示安装画面(这个最常用)。
/M
跳过安装时音频(.wav)文件的播放。
/N
没有鼠标时运行Setup。
/NA#
# =0 缺省
# =1 不检查基于Windows的程序,排列基于MS-DOS的程序
# =2不检查基于MS-DOS的程序,排列基于的Windows程序
# =3不检查基于Windows和MS-DOS的程序
/ND
忽略Migration.dll文件,并强制Windows98覆盖较新的文件
/NF
在“复制Windows98文件至你的计算机”结束后,不显示“从驱动器A
中移去软盘”。一般在用户用可启动光盘安装Windows98时使用该参数
。等价于在Msbatch.inf文件中设置BootCD=1。
/NH
在Windows95用户界面运行Setup时,不运行Hwinfo.exe。
/nm
忽略检查运行Windows98所需的最低要求处理器(66MHz 486)。
/NOSTART
复制安装Windows98所需的动态链接库文件(DLLs)的最小安装版本,然
后不安装Windows98而直接退回MS-DOS状态。
/NR
忽略注册表检查。
/NX
不检查正在运行的Setupx的版本。
/PI
保留硬件的特定设置(硬件未使用缺省设置)。有的版本的BIOS要求
硬件根据特定的设置工作。默认情况下,Setup删除硬件的特定设置从
而造成部分硬件不能正常工作。
/PJ
默认安装Advanced Configuration and Power Interface (ACPI)
script_filename
使用指定位置的包含安装选项的宏文件自动安装Windows98。
/SRCDIR
指定Windows98安装文件的初始目录
/S filename
安装时装载指定的SETUP.INF文件。
/T:tempdir
为安装程序指定复制临时文件的目录。如果目录不存在,将自动创建
该目录。若该目录存在,则此目录中的任何旧文件都将被删除。
/U:UPI
指定UPI
/IV
在安装过程跳过公告板显示(这个最常用)
/IW
在安装过程跳过许可协议显示(这个最常用)
/IX
忽略字符集检查
例子:我们一般这要用到这几个参数就够了
setup /is /iv /im /iw Autobatch.inf
如果要了解更详细的内容请登上微软的网站:
http://support.microsoft.com/ph/1139
使用自动安装脚本文件全自动安装 Windows 98 的格式为:Setup *:\Autobatch.inf (注:必须包括完整路径!)。
三、修改 setup98.img 文件
我们已经做了上述的准备,这里就只要简单的修改一下映像文件就行了,
1、如果我们是把所做好的映像文件IMG直接添加到引导区的话,那么 setup98.img 里的 jo.sys 保留着,在安装时
Windows 98 在重启动时会很好地帮助你进入安装程序,不然你会感到没有完全自动了,因为它默认的是从硬盘启
动,如果你是用 EasyBoot 菜单来调用做全自动安装的话,请你把这个 jo.sys 这个文件删除掉,否则又会带来不
便。
2、用 Winimage 打开 setup98.img 修改文件,提取 autoexec.bat 文件,把这句 OEMSETUP.EXE /K "/IE /NF" 命令改成下面的就 OK 了,
%CDROM%:\SETUP /IS /IV /IM /IW AUTOBATCH.INF (注:这个AUTOBATCH.INF文件必须在安装程序目录下)

也可用自定义目录来安装,比如:我们建立一个配置文件目录,取名为 AUTO 目录.
%CDROM%:\SETUP /IS /IV /IM /IW %CDROM%:\AUTO\AUTOBATCH.INF
也可以把配置应答文件放在硬盘上,
%CDROM%:\SETUP /IS /IV /IM /IW D:\AUTO\AUTOBATCH.INF(必须完整路径)
3、修改完成后,把 autoexec.bat 文件添加进 setup98.img 修改文件进行覆盖原文件就行了。

第五课《启动盘实战系列二, 全自动备份和恢复的IMG映像》
在这篇里讲解做一个全自动备份和恢复的 IMG 映像文件, 其实做这个启动盘也不难的, 只要用 Windows 98 的 标准 IMG 来做一下修改就行了, 很简单的, 所需的工具这要一个 Winimage 映像编辑软件就行了。
因为现在大家都在想学电脑,装程序等等!一旦程序或系统出了严重的问题需重装系统是一件
很烦的事,自从有了 GHOST 程序后,就变得很轻松了,这要先装好一个干净健康的系统用 GHOST 程序做备份,一旦系统出问题,只要把这个启动盘一放后启动电脑后一键就搞定,真是轻松多了。
注:因为详细的命令在以几篇中都已讲过,所以不再详解,现在这是实例了
一、利用 Windows 98 的 标准 IMG 启动映像来改制自己想要的备份和恢复启动盘, 首先把 IMG
映像文件里的二个文件 config.sys 和 autoexec.bat 这二个提取出来,然后再进行修改。
1、config.sys 的文件做修改
============================================================================
[menu]
menuitem=CD, Start computer with CD-ROM support.
menuitem=NOCD, Start computer without CD-ROM support.
menuitem=HELP, View the Help file.
menudefault=CD,30
menucolor=7,0
[CD]
device=himem.sys /testmem:off
device=oakcdrom.sys /D:mscd001
device=btdosm.sys
device=flashpt.sys
device=btcdrom.sys /D:mscd001
device=aspi2dos.sys
device=aspi8dos.sys
device=aspi4dos.sys
device=aspi8u2.sys
device=aspicd.sys /D:mscd001
[NOCD]
device=himem.sys /testmem:off
[HELP]
device=himem.sys /testmem:off
[COMMON]
files=10
buffers=10
dos=high,umb
stacks=9,256
devicehigh=ramdrive.sys /E 2048
lastdrive=z
================================================================================
改成为这样,
如下: (把下面的红色字全部复制一份到 config.sys 里就可以了,原来的全部覆盖)
================================================================================
[color=#ff0000]
[menu]
menuitem=CD, Ghsot Huifu from CDROM to C Disk 从光盘恢复到 C 盘
menuitem=DISK1, Ghsot Huifu from F Disk to C disk 从 F 盘恢复到 C 盘
menuitem=DISK2, Ghost Beifen C Disk to F Disk 备份 C 盘到 F 盘
menudefault=CD,30
menucolor=7,0
[CD]
device=himem.sys /testmem:off
device=oakcdrom.sys /D:mscd001
device=btdosm.sys
device=flashpt.sys
device=btcdrom.sys /D:mscd001
device=aspi2dos.sys
device=aspi8dos.sys
device=aspi4dos.sys
device=aspi8u2.sys
device=aspicd.sys /D:mscd001
[DISK1]
device=himem.sys /testmem:off
[DISK2]
device=himem.sys /testmem:off
[COMMON]
files=10
buffers=10
dos=high,umb
stacks=9,256
devicehigh=ramdrive.sys /E 2048
lastdrive=z

=============================================================================
config.sys 的以下菜单[menu] 和 [CD] 修改好就可以了 [DISK1] 和 [DISK2] 项都不需
要修改的,只修改一下标签就行了,其实不修改标签也一样可以,我们只是为了放便记住
它,不会搞错,所以还是修改一下的好。其它它用默认就可以了。
2、autolexec.bat 文件的做修改
==============================================================================
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
cls
call setramd.bat %LglDrv%
set temp=c:\
set tmp=c:\
path=%RAMD%:\;a:\;%CDROM%:\
copy command.com %RAMD%:\ > NUL
set comspec=%RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL
copy readme.txt %RAMD%:\ > NUL
:ERROR
IF EXIST ebd.cab GOTO EXT
echo Please insert Windows 98 Startup Disk 2
echo.
pause
GOTO ERROR
:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
echo The diagnostic tools were successfully loaded to drive %RAMD%.
echo.
IF "%config%"=="NOCD" GOTO QUIT
IF "%config%"=="HELP" GOTO HELP
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM%
echo.
GOTO QUIT
:HELP
cls
call help.bat
echo Your computer will now restart and the startup menu will appear.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
restart.com
GOTO QUIT
:QUIT
echo To get help, type HELP and press ENTER.
echo.
rem clean up environment variables
set CDROM=
set LglDrv=
================================================================================
改成这样:
如下: (把下面的红色字全部复制一份到 autolexec.bat 里就可以了,原来的全部覆盖)
================================================================================
[color=#ff0000]
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
cls
call setramd.bat %LglDrv%
set temp=c:\
set tmp=c:\
path=%RAMD%:\;a:\;%CDROM%:\
copy command.com %RAMD%:\ > NUL
set comspec=%RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL
copy readme.txt %RAMD%:\ > NUL
:ERROR
IF EXIST ebd.cab GOTO EXT
echo Please insert Windows 98 Startup Disk 2
echo.
pause
GOTO ERROR
:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
echo The diagnostic tools were successfully loaded to drive %RAMD%.
echo.
IF "%config%"=="CD" GOTO HUIFU1
IF "%config%"=="DISK1" GOTO HUIFU2
IF "%config%"=="DISK2" GOTO BEIFEN
:HUIFU1
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM%
%CDROM%:\ghost.exe -clone,mode=pload,src=%CDROM%:\xp.gho:1,dst=1:1 -sure -rb
:HUIFU2
f:\ghost.exe -clone,mode=pload,src=f:\xp.gho:1,dst=1:1 -sure -rb
:BEIFEN
f:\ghost.exe -clone,mode=pdump,src=1:1,dst=f:\xp.gho -fx -sure -z9 -rb
:QUIT
echo To get help, type HELP and press ENTER.
echo.
rem clean up environment variables
set CDROM=
set LglDrv=

==================================================================================
以上的修改完成后,把它导入到 SETUP98.IMG 映像中覆盖原文件即可,这样我们所做的自动
备份和恢复就完成了。
二、下面将 GHOST 程序详细说明也发一下
Ghost 使用详解
--------------------------------------------------------------------------------
一、分区备份
  使用Ghost进行系统备份,有整个硬盘(Disk)和分区硬盘(Partition)两种方式。在菜单中点击 Local(本地)项,在右面弹出的菜单中有3个子项,其中 Disk表示备份整个硬盘(即克隆)、Partition 表示备份硬盘的单个分区、Check 表示检查硬盘或备份的文件,查看是否可能因分区、硬盘被破坏等造成备份或还原失败。分区备份作为个人用户来保存系统数据,特别是在恢复和复制系统分区时具有实用价值。
  选 Local→Partition→To Image 菜单,弹出硬盘选择窗口,开始分区备份操作。点击该窗口中白色的硬盘信息条,选择硬盘,进入窗口,选择要操作的分区(若没有鼠标,可用键盘进行操作:TAB键进行切换,回车键进行确认,方向键进行选择)。 在弹出的窗口中选择备份储存的目录路径并输入备份文件名称,注意备份文件的名称带有 GHO 的后缀名。 接下来,程序会询问是否压缩备份数据,并给出3个选择:No 表示不压缩,Fast表示压缩比例小而执行备份速度较快,High 就是压缩比例高但执行备份速度相当慢。最后选择 Yes 按钮即开始进行分区硬盘的备份。Ghost 备份的速度相当快,不用久等就可以完成,备份的文件以 GHO 后缀名储存在设定的目录中。

二、硬盘克隆与备份
  硬盘的克隆就是对整个硬盘的备份和还原。选择菜单Local→Disk→To Disk,在弹出的窗口中选择源硬盘(第一个硬盘),然后选择要复制到的目标硬盘(第二个硬盘)。注意,可以设置目标硬盘各个分区的大小,Ghost 可以自动对目标硬盘按设定的分区数值进行分区和格式化。选择 Yes 开始执行。
  Ghost 能将目标硬盘复制得与源硬盘几乎完全一样,并实现分区、格式化、复制系统和文件一步完成。只是要注意目标硬盘不能太小,必须能将源硬盘的数据内容装下。
  Ghost 还提供了一项硬盘备份功能,就是将整个硬盘的数据备份成一个文件保存在硬盘上(菜单 Local→Disk→To Image),然后就可以随时还原到其他硬盘或源硬盘上,这对安装多个系统很方便。使用方法与分区备份相似。

三、备份还原
  如果硬盘中备份的分区数据受到损坏,用一般数据修复方法不能修复,以及系统被破坏后不能启动,都可以用备份的数据进行完全的复原而无须重新安装程序或系统。当然,也可以将备份还原到另一个硬盘上。
  要恢复备份的分区,就在界面中选择菜单Local→Partition→From Image,在弹出窗口中选择还原的备份文件,再选择还原的硬盘和分区,点击 Yes 按钮即可。

四、局域网操作
LPT 是通过并口传送备份文件,下面有两个选项:slave 和 master, 分别用以连接主机和客户机。 网络基本输入输出系统 NetBios 和 LPT 相似, 也有 slave 和 master 两个选项, 作用与 LPT 相同。
先和平时一样将要 ghost 的分区做成一个 *.gho 文件,再在一台 win98 上安装Symantec Ghost 企业版,重启。
1. 首先制作一张 ghost 带网卡驱动的启动盘。Start > Programs > Symantec Ghost > Ghost Boot Wizard->Network Boot Disk 如果你的网卡在列表内直接选择它就可以生成一张带 PC-DOS 的启动盘。(但 6.5版的生成的软盘经常有问题,不能成功启动)如果你的网卡不在列表内,你要建立专用的 Packet Driver。ADD->Packet Driver (网卡的驱动程序中有)往下根据提示一步一步走,填入工作站的 ip(ghost 一定要 tcp/ip 协议)。最后生成一张软盘,但此软盘仍不能使用,要改 autoexec.bat 文件在 net xxxx.dos 后面加一个16进制的地址,如 0X75 等。多台计算机只需改 wattcp.cfg 文件中的 ip 即可:
IP = 192.168.100.44
NETMASK = 255.255.255.0
GATEWAY = 192.168.100.1
2. 在 server 端运行 multicast server 出来的画面。先给 server一个Session Name(别名)如:bb,再选择 image file 就是你的 gho 文件。然后 ->Dump From Client->rtitions->More Options-> 在 auto start 的 client 中填入 50(如果你要同时复制50台)->accept client 就算完成了,当你的工作站数达到50台时,server就自动传送*.gho 文件。
3.详述:
目前,相当多的电子教室都采用了没有软驱、光驱的工作站。在没有软驱、光驱的情况下,当硬盘的软件系统出现问题时,能否实现网络硬盘克隆呢?PXE(Preboot Execution Environment,它是基于 TCP/IP、DHCP、TFTP 等 Internet 协议之上的扩展网络协议)技术提供的从网络启动的功能,让我们找到了解决之道。下面,我们就来讲解怎样采用Ghost 7.0来实现基于 PXE 的网络硬盘克隆。
  网络硬盘克隆过程简述
  网络硬盘克隆过程为:在装有软驱的工作站上,用一张引导盘来启动机器,连接到服务器,使用 Ghost 多播服务(Multicast Server)将硬盘或分区的映像克隆到工作站,这样就实现了不拆机、安全、快速的网络硬盘克隆。
  实现 PXE 网络启动方式
  对于没有软驱、光驱的工作站,要实现PXE网络启动方式,需要完成三个步骤:
  1、工作站的PXE启动设置
  PXE网络启动一般要求在网卡上加装 PXE 启动芯片(PXE Boot ROM);对于某些型号的网卡,也可以将 PXE 启动代码(Boot Code)写入主板的 Flash ROM;而一些主板上集成了网卡的品牌机(例如清华同方的商用机),可直接支持PXE启动。
  常用的 RTL8139 芯片的网卡,其 PXE 启动设置方式是:机器启动时根据屏幕提示按下Shift+F10,在启动类型中选择PXE,开启网络启动选项即可。
  2、制作 PXE 启动文件
  制作 PXE 的启动文件,推荐使用 3Com 的 DABS(Dynamic Access Boot Services)。DABS 提供了功能强大的 PXE 启动服务、管理功能,但是,网上可供下载的是一个30天的试用版。所以,我们只用它的启动映像文件制作功能,而由 Windows 2000 Server 的 DHCP 服务器来提供 PXE 启动服务。
  DABS 可以安装在任何一台运行 Windows 的机器上。安装后,运行 3Com Boot Image Editor,出现主界面图。选择“创建TCP/IP或PXE映像文件(Create a TCP/IP or PXE image file)”,出现对话窗口。为即将建立的映像文件命名,例如:pxeghost.img,其他采用默认选项,将经测试正常的网络启动盘放入软驱,选择[OK],创建PXE启动映像 Pxeghost.img文件。
  在 3Com Boot Image Editor 的主菜单中,选择“创建PXE菜单启动文件(Creat a PXE menu boot file)”,在出现的窗口中选择[添加(Add)],加入我们刚刚创建的启动映像文件Pxeghost.img,在“选项(Options)”标签中可以设置菜单标题和等待时间。
  选择[保存(Save)],给保存的PXE菜单启动文件命名为 Pxemenu.pxe。
  3、服务器的PXE启动服务设置
  Windows 2000 Server 的 DHCP 服务支持两种启动协议:DHCP 和 BOOTP。我们可以设定以下三种选择:仅 DHCP、仅 BOOTP、两者。如果我们的局域网中由其他的 DHCP 服务器提供动态 IP 地址分配,那么这里选“仅BOOTP”即可;如果需要这台服务器提供动态 IP 地址分配,则需要选“两者”。
  接下来,设置启动文件名。在DHCP服务器的作用域选项中配置选项“067:启动文件名”,字串值为我们创建的 PXE 菜单启动文件名 Pxemenu.pxe。注意:文件名不包含路径。
  DHCP 服务器只是将启动文件名通知给 BOOTP 客户机,客户机通过什么方式下载启动文件呢?答案是,需要 TFTP 服务。3Com 的 DABS 包含了一个 TFTP 服务组件,当然,也可以下载一个免费的 TFTP 服务器软件长期使用。
  在 TFTP 服务器的设置中,规定一个服务目录。将制作的 PXE 启动文件 Pxeghost.img、Pxemenu.pxe 放到 TFTP 的服务目录中。TFTP 服务器设置为自动运行。
  用 Ghost 多播克隆硬盘
  现在运行 Ghost 多播服务器,任务名称为 Restore。设置完毕,按下[接受客户(Accept Clients)]按钮。启动要接受硬盘克隆的无软驱工作站,如果以上步骤操作无误,应该能够实现 PXE 启动,加入到多播克隆的任务当中。所有的目标工作站连接到本次任务之后,按下[发送(Send)]按钮,开始克隆任务。
五、参数设置
在 Options 中可以设置参数。下面简单介绍一下:
1.image write buffering:在建立备份文件时, 打开写缓冲;
2.sure:选择此项后, 不再会出现最终确认询问 (建议不要选择此项);
3.no int 13:选择此项后, 不支持中断 13 (缺省时不选择);
4.reboot:在对硬盘或者分区操作完成之后, 自动重启计算机;
5.spanning:通过多个卷架构备份文件 (选择此项时, 关闭 write buffering);
6.autoname:自动为 spanning 文件命名;
7.allow 64k fat clusters:允许使用 64K FAT 簇 (仅在 Windows NT 中支持);
8.ignore CRC errors:忽略 CRC 错误;
9.override size limit:如果出现分区大小不相配, 可忽略执行;
10.image read buffering:打开生成备份文件时的读缓存 (缺省时选中此项)。

六、软件特性
1.存贮介质
  Ghost 支持的存储介质超出了我们的想象,它支持对等 LPT 接口、对等 USB 接口、对等 TCP/IP 接口、SCSI磁带机、便携式设备(JAZ、ZIP、MO等)、光盘刻录机(CDR、CDRW)等。而这些特性不需要任何外带的驱动程序和软件,只需一张软盘就可以做到!特别是对光盘刻录机的支持,如今的刻录机和空白光盘都十分便宜,非常适合作备份的用途。
2.兼容性
  Ghost 对现有的操作系统都有良好的支持,包括 FAT16、FAT32、NTFS、HPFS、UNIX、NOVELL 等文件存储格式。同以前版本不同的是,Ghost 2001 加入了对 Linux EX2的支持(FIFO 文件存储格式),这也就意味着 Linux 的用户也可以用 Ghost 来备份系统了。
3.配套软件
  A.Ghost 浏览器
在以前的 Ghost版本中,我们只能对整个系统进行简单的备份、复制、还原,要恢复单个的文件和文件夹还要使用外带的 GhostEXP 软件。现在,Symantec 公司已经将 Ghost 浏览器整合在软件中。Ghost 浏览器采用类似于资源管理器的界面,通过它,我们可以方便迅速地在备份包中找出我们想要的文件和文件夹并还原。
使用Explorer可以备份整个硬盘或单个硬盘分区,点击工具栏上的圆柱形图标,弹出硬盘或分区选择对话窗口,然后再选择备份文件的储存目录并输入名称即可完成。要注意的是,非注册用户不能使用备份这项功能。
在 Ghost Explorer 中管理硬盘备份文件就非常方便了。首先选择打开一个备份文件(File/Open),这时备份中的文件就像资源管理器一样在程序界面窗口中列出,可以在其中非常方便地查看、打开文件,也可以查找文件,或者将某个文件删除(但不能删除目录)。
在 Ghost Explorer 中提供了多种还原硬盘备份文件的方法,最方便的方法是使用鼠标右键点击某个文件,在弹出菜单中选择 Restore,然后输入要还原到的目录,这样,单个文件就从整个磁盘备份中还原出来了。当然,如果要还原整个磁盘备份,只需选择左面目录列表栏中最上面的带磁盘图标的目录项,然后点击工具栏中的还原图标 (第二个) 就可以了。
B.GDisk
GDisk 是一个新加入的实用工具,它彻底取代了 FDisk 和 format,功能有:
* 快速格式化。
* 隐藏和显示分区。此功能允许一个以上的主 DOS分区,并且每个分区上的操作系统有不同的版本。隐藏分区的能力使计算机习惯于引导到选定的可引导分区,忽略其他隐藏分区中相同操作系统的安装。
* 全面的分区报告。
* 高度安全的磁盘擦除。提供符合美国国防部标准和更高安全标准的磁盘擦除选项。
与使用交互式菜单的 FDisk 不同,GDisk是由命令行驱动的。这提供了更快的配置磁盘分区和在批处理文件中定义 GDisk操作的能力。但与此同时,几十个参数会令普通用户头疼,因此笔者不推荐一般用户使用,Symantec 公司也应该推出相应的GUI(图形用户界面)控制台以方便用户使用。具体的参数说明可以用命令行 gdisk/? 了解。
C.Live Update
Live Update 是 Symantec公司软件的一个通用升级程序,它能够检查当前系统中已安装的 Symantec 软件,并且通过英特网对软件进行在线升级。
在安装 Ghost 2001 时,安装程序自动升级了 Live Update 程序的版本。

七、命令行参数:(Ghost 的无人 备份/恢复/复制 操作)
  其实 Ghost 2001 的功能远远不止它主程序中显示的那些,Ghost 可以在其启动的命令行中添加众多参数以实现更多的功能。命令行参数在使用时颇为复杂,不过我们可以制作批处理文件,从而“一劳永逸”(类似于无人安装 Windows 98 和Windows 2000)。现在让我们来了解一些常用的参数(了解更加详细的参数介绍可查看 Ghost 的帮助文件)。
1.-rb
本次 Ghost 操作结束退出时自动重启。这样,在复制系统时就可以放心离开了。
2.-fx
本次 Ghost 操作结束退出时自动回到DOS提示符。
3.-sure
对所有要求确认的提示或警告一律回答“Yes”。此参数有一定危险性,只建议高级用户使用。
4.-fro
如果源分区发现坏簇,则略过提示而强制拷贝。此参数可用于试着挽救硬盘坏道中的数据。
5.@filename
在 filename 中指定 txt 文件。txt文件中为 Ghost 的附加参数,这样做可以不受DOS命令行 150 个字符的限制。
6.-f32
将源 FAT16 分区拷贝后转换成 FAT32(前提是目标分区不小于 2G)。WinNT 4 和Windows95、97用户慎用。
7.-bootcd
当直接向光盘中备份文件时,此选项可以使光盘变成可引导。此过程需要放入启动盘。
8.-fatlimit
将 NT 的 FAT16 分区限制在 2G。此参数在复制 Windows NT 分区,且不想使用64k/簇的 FAT16 时非常有用。
9.-span
分卷参数。当空间不足时提示复制到另一个分区的另一个备份包。
10.-auto
分卷拷贝时不提示就自动赋予一个文件名继续执行。
11.-crcignore
忽略备份包中的 CRC ERROR。除非需要抢救备份包中的数据,否则不要使用此参数,以防数据错误。
12.-ia
全部映像。Ghost 会对硬盘上所有的分区逐个进行备份。
13.-ial
全部映像,类似于 -ia 参数,对 Linux 分区逐个进行备份。
14.-id
全部映像。类似于 -ia 参数,但包含分区的引导信息。
15.-quiet
操作过程中禁止状态更新和用户干预。
16.-script
可以执行多个 Ghost 命令行。命令行存放在指定的文件中。
17.-split=x
  将备份包划分成多个分卷,每个分卷的大小为 x兆。这个功能非常实用,用于大型备份包复制到移动式存储设备上,例如将一个 1.9G 的备份包复制到 3 张刻录盘上。
18.-z
  将磁盘或分区上的内容保存到映像文件时进行压缩。-z 或 -z1 为低压缩率(快速);-z2 为高压缩率(中速);-z3 至 -z9 压缩率依次增大(速度依次减慢)。
19.-clone
  这是实现 Ghost 无人备份/恢复的核心参数。使用语法为:
-clone,MODE=(operation),SRC=(source),DST=(destination),[SZE(size),SZE(size)...]
此参数行较为复杂,且各参数之间不能含有空格。其中 operation意为操作类型,值可取:copy:磁盘到磁盘;load:文件到磁盘;dump:磁盘到文件;pcopy:分区到分区;pload:文件到分区;pdump:分区到文件。
  Source 意为操作源,值可取:驱动器号,从1开始;或者为文件名,需要写绝对路径。
Destination 意为目标位置,值可取:驱动器号,从 1开始;或者为文件名,需要写绝对路径;@CDx,刻录机,x 表示刻录机的驱动器号,从1开始。
下面举例说明:
1.命令行参数:ghostpe.exe -clone,mode=copy,src=1,dst=2
完成操作:将本地磁盘1复制到本地磁盘2。
2.命令行参数:ghostpe.exe -clone,mode=pcopy,src=1:2,dst=2:1
完成操作:将本地磁盘1上的第二分区复制到本地磁盘2的第一分区。
3.命令行参数:ghostpe.exe-clone,mode=load,src=g:\3prtdisk.gho,dst=1,sze1=450M,sze2=1599M,sze3=2047M
完成操作:从映像文件装载磁盘1,并将第一个分区的大小调整为450MB,第二个调整为1599MB,第三个调整为2047MB。
4.命令行参数:ghostpe.exe -clone,mode=pdump,src2:1:4:6,dst=d:\prt246.gho
完成操作:创建仅含有选定分区的映像文件。从磁盘2上选择分区1、4、6。

八、一些示例
ghost.exe -clone,mode=copy,src=1,dst=2 -sure
硬盘对拷
ghost.exe -clone,mode=pcopy,src=1:2,dst=2:1 -sure
将一号硬盘的第二个分区复制到二号硬盘的第一个分区
ghost.exe -clone,mode=pdump,src=1:2,dst=g:\bac.gho
将一号硬盘的第二个分区做成映像文件放到 g 分区中
ghost.exe -clone,mode=pload,src=g:\bac.gho:2,dst=1:2
从内部存有两个分区的映像文件中,把第二个分区还原到硬盘的第二个分区
ghost.exe -clone,mode=pload,src=g:\bac.gho,dst=1:1 -fx -sure -rb
用 g 盘的 bac.gho 文件还原 c 盘。完成后不显示任何信息,直接启动
ghost.exe -clone,mode=load,src=g:\bac.gho,dst=2,SZE1=60P,SZE2=40P
将映像文件还原到第二个硬盘,并将分区大小比例修改成 60:40
自动还原磁盘:
首先做一个启动盘,包含 Config.sys, Autoexec.bat, Command.com, Io.sys, Ghost.exe 文件(可以用 windows 做启动盘的程序完成)。Autoexec.bat 包含以下命令:
Ghost.exe -clone,mode=pload,src=d:\bac.gho,dst=1:1 -fx -sure -rb
利用在 D 盘的文件自动还原,结束以后自动退出 ghost 并且重新启动。
自动备份磁盘:
ghost.exe -clone,mode=pdump,src=1:1,dst=d:\bac.gho -fx -sure -rb
自动还原光盘:
包含文件:Config.sys, Autoexec.bat, Mscdex.exe (CDROM 执行程序), Oakcdrom.sys (ATAPI CDROM 兼容驱动程序), Ghost.exe。
Config.sys 内容为:
DEVICE=OAKCDROM.SYS /D:IDECD001
Autoexec.bat 内容为:
MSCDEX.EXE /D:IDECE001 /L:Z
Ghost -clone,mode=load,src=z:\bac.gho,dst=1:1 -sure -rb
可以根据下面的具体说明修改示例:
1.-clone
-clone 在使用时必须加入参数,它同时也是所有的 switch{batch switch} 里最实用的。下面是 clone 所定义的参数:
mode={copy|load|dump|pcopy|pload|pdump},
src={drive|file|driveartition},
dst={drive|file|driveartition}
mode 指定要使用哪种 clone 所提供的命令
copy 硬盘到硬盘的复制 (disk to disk copy)
load 文件还原到硬盘 (file to disk load)
dump 将硬盘做成映像文件 (disk to file dump)
pcopy 分区到分区的复制 (partition to partition copy)
pload 文件还原到分区 (file to partition load)
pdump 分区备份成映像文件(partition to file dump)
src 指定了 ghost 运行时使用的源分区的位置模式及其意义。对应 mode 命令 src 所使用参数例子:
COPY/DUMP 源硬盘号。以 1 代表第一号硬盘
LOAD 映像文件名。g:/back98/setup98.gho 或装置名称 (drive)
PCOPY/PDUMP 源分区号。1:2 代表的是硬盘1的第二个分区
PLOAD 分区映像文件名加上分区号或是驱动器名加上分区号。g:\back98.gho:2 代表映像文件里的第二个分区
dst 指定运行 Ghost 时使用的目标位置模式及其意义。对应 mode 命令 dst 所使用参数例子:
COPY/DUMP 目的硬盘号。2 代表第二号硬盘
LOAD 硬盘映像文件名。例 g:\back98\setup98.gho
PCOPY/PLOAD 目的分区号。2:2 代表硬盘 2 的第二个分区
PDUMP 分区映像文件名加分区号。g:\back98\setup98.gho:2
SZEn 指定所使用目的分区的大小:
n=xxxxM 指定第 n 目的分区的大小为 xxxxMB。如 SZE2=800M 表示分区 2 的大小为 800MB
n=mmP 指定第 n 目的分区的大小为整个硬盘的 mm 个百分比。
2.-fxo 当源物件出现坏块时,强迫复制继续进行
3.-fx 当ghost完成新系统的工作后不显示 press ctrl-alt-del to reboot 直接回到DOS下
4.-ia 完全执行扇区到扇区的复制。当由一个映像文件或由另一个硬盘为来源,复制一个分区时,Ghost将首先检查来源分区,再决定是要复制文件和目录结构还是要做映像复制(扇区到扇区)。预设是这种形式。但是有的时候,硬盘里特定的位置可能会放一些隐藏的与系统安全有关的文件。只有用扇区到扇区复制的方法才能正确复制
5.-pwd and -pwd=x 给映像文件加密
6.-rb 在还原或复制完成以后,让系统重新启动
7.-sure 可以和 clone 合用。Ghost 不会显示 proceed with disk clone-destination drive will be overwritten? 提示信息
九、注意事项
1.在备份系统时,单个的备份文件最好不要超过 2GB。
2.在备份系统前,最好将一些无用的文件删除以减少Ghost文件的体积。通常无用的文件有:Windows 的临时文件夹、IE 临时文件夹、Windows 的内存交换文件。这些文件通常要占去100 多兆硬盘空间。
3.在备份系统前,整理目标盘和源盘,以加快备份速度。
4.在备份系统前及恢复系统前,最好检查一下目标盘和源盘,纠正磁盘错误。
5.在恢复系统时,最好先检查一下要恢复的目标盘是否有重要的文件还未转移,千万不要等硬盘信息被覆盖后才后悔莫及啊。
6.在选择压缩率时,建议不要选择最高压缩率,因为最高压缩率非常耗时,而压缩率又没有明显的提高。
7.在新安装了软件和硬件后,最好重新制作映像文件,否则很可能在恢复后出现一些莫名其妙的错误。

第六课《启动盘实战系列三, 支持多光驱和 NTFS 分区 IMG 映像》
在上篇里讲到做一个全自动备份和恢复的 IMG 映像文件, 在这篇里我们要学做的是带菜单格式的多功能启动盘,可以做成有以下功能:① 全自动 GHOST ; ② 启动到 DOS 下手支操作; ③ DM 分区等等。其实做这个启动盘也不难的, 只要用 Windows 98 的 启动盘 IMG 来做一下修改, 需要修改好多地方,这样做好的 IMG 启动盘必须要用其它软件来调用,因它超过了 1.44 MB,不能直接加载到引导扇区,但如果把其它工具都放到光盘上,也是可以不用软件来调用的,只要把这个启动盘一放进光驱启动电脑后就可对相应的功能操作了,一键就搞定,真是轻松多了。
注:因为详细的命令在以前几篇中都已讲过,所以不再详解,现在这是实例了
第一步 认识多光驱支持的原理,看下面的全自动 GHSOT 的详细解释,如下:
这是一个全自动的克隆 autohf.bat 文件,可以直接复制红色文字到这个批处理中。在其它的地方
可以用这个方法来调用其它程序和小工具,这要改一下路径就行了,简单的很,在下面就有调用到
其它的方法。
======================================================================================
[color=#ff0000]
:: 测试虚拟盘是否建立成功
dready z: /w
if errorlevel 1 goto _errramd
:: 建立testdrv.bat临时文件到虚拟盘上
set td=Z:\testdrv.bat
> %td% echo @echo off
>> %td% echo dready %%1
>> %td% echo if errorlevel 1 goto _quit
>> %td% echo set CDOK=%%CDOK%% %%1
>> %td% echo :_quit
:: 调用mscdex为所有光驱分配盘符
LH MSCDEX.EXE /D:mscd001
set CDROM=
findcd /s > nul
:: 调用testdrv.bat检测哪些光驱中有盘并将准备好的光驱保存到cdok变量中
SET CDOK=
for %%I in (%cdrom1% %cdrom2% %cdrom3%) DO call %td% %%I
::检测哪些准备好的光驱中存在需要的GHO文件,并将结果保存到bootcd变量中
set bootcd=
for %%I in (%cdok%) DO if exist %%I\XPSP2\XP-SP2.GHO set BOOTCD=%%I
:: 检测是否存在需要的启动光盘
IF %BOOTCD%*==* goto _nobootcd
set CDROM=%bootcd%
echo bootcd=%bootcd%
goto _findbootcdok
:: 找不到所需启动光盘的错误提示
:_nobootcd
echo.
echo Error: I cannot find your CDROM where we boot from!
echo Please make sure you insert the boot disc in it!
pause
goto _quit
:: 如果存在gho文件,则执行ghost过程并重新启动
:_findbootcdok
%CDROM%\XPSP2\ghost.exe -clone,mode=pload,src=%CDROM%\XPSP2\XP-SP2.gho:1,dst=1:1 -sure -fx
::这是当GHOST工作完成后反回主菜单,在用EASYBOOT调用下,不调用下不要用这参数。
wboot.com
goto _quit
:: 没有成功建立内存虚拟磁盘的错误提示
:_errramd
echo.
echo Error: I cannot access your RAM Disk at Q:!
echo Check if xmsdsk can create RAM Disk.
pause
goto _quit
:: 退出,清理环境变量
:_quit
for %%I in (cdrom1 cdrom2 cdrom3 cdok) do set %%I=

====================================================================================
知道上面的过程后,也就是这样一个过程,也并不过的,(注意:带双冒号的是注解文字用的,
复制到批处理里并不需要将其删除,可以直接使用)
第二步 开始制作多功能启动盘了
1、找一个 98 启动盘IMG文件;
2、用 Winimage 把里面的所有文件全部提取到一个文件夹中。然后删除IMG里的所有文件,仅留
下这 Io.sys 、 msdos.sys 、 command.com 文件及建立二个目录,一个是 DM 目录、一个 temp
是临时目录。然后把刚才提取的 ebd.cab 这个文件解压到一个 ebd 目录中,在 ebd 目录下再建
立一个目录,目录名为 DATA ,再把 DOS 下所用的 五笔和拼音及区位码这 WB.MB、PY.MB、LX.LX
三个文件复制到 DATA 目录里,然后再重新制作 ebd.cab 文件,(五笔和拼音及区位码这些文件
可以 DM 9.56 双语版中提取)
其它的我们在后面加进去。
3、修改 CONFIG.SYS 文件为以下内容:
====================================================
[color=#ff0000]
device=himem.sys /testmem:off
device=emm386.exe noems
device=oakcdrom.sys /D:mscd001
dos=high,umb
files=30
buffers=20

====================================================
把以上这 himem.sys、emm386.exe、oakcdrom.sys 三个文件加到IMG文件中,
4、修改 AUTOEXEC.BAT 文件为以下内容:
====================================================
[color=#ff0000]
@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
cls
SET RAMD=Z
XMSDSK 9816 Z: /y
set temp=%RAMD%:\
set tmp=%RAMD%:\
mouse > NUL
FINDCD.EXE > NUL
path=%RAMD%:\;a:\;%CDROM%:\
copy command.com %RAMD%:\ > NUL
copy extract.exe %RAMD%:\ > NUL
:ERROR
IF EXIST ebd.cab GOTO EXT
echo Please insert Windows 98 Startup Disk 2
echo.
pause
GOTO ERROR
:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
cls
GOTO QUIT
:QUIT
set CDROM=
set LglDrv=
cls
tw > NUL
echo.
echo.
echo.
echo.
echo.
echo 内存虚拟磁盘已被成功创建,当前虚拟工作盘符为 %RAMD% 盘。
echo.
echo 所需的工具都从 EBD.CAB 压缩包中被释放到虚拟 %RAMD% 盘中。
echo.
echo.
echo.
echo.
a:
zmenu.bat

====================================================
再把 AUTOEXEC.BAT 所需用的文件加入到 IMG 文件中。文件如下:
xmsdsk.exe、FINDCD.EXE、extract.exe、ebd.cab、tw.exe
5、主菜单的制作,我们现在以 7 个菜单项做实习,请看以下批处理文件,取名为 ZMENU.BAT
ZMENU.BAT 批处理文件内容如下:
==================================================================================
[color=#ff0000]
@echo off
tw > nul
@echo off
echo.
echo 中文多功能 MS-DOS 系统启动盘
echo ============================================================
echo.
echo 1、全自动从光盘上克隆 Windows XP SP2 专业版
echo 2、从光盘上安装 Windows 98 SE
echo 3、带光驱驱动的中文 Dos 命令行启动模式
echo 4、克隆恢复从 E 盘 Tools 恢复到 C 盘模式
echo 5、启动运行 DM 9.57 中英文双语版分区程序
echo 6、进入查看 NTFS 分区
echo 7、工具箱 》》》
echo.
choice/c:1234567 /t:2,999 . 请在上面选项中选择相应的数字键值。
if errorlevel 7 goto menu_7
if errorlevel 6 goto menu_6
if errorlevel 5 goto menu_5
if errorlevel 4 goto menu_4
if errorlevel 3 goto menu_3
if errorlevel 2 goto menu_2
if errorlevel 1 goto menu_1
:menu_1
cls
call autohf.bat
goto quit
:menu_2
cls
call 98se.bat
goto quit
:menu_3
cls
call doscd.bat
goto cdrom
:menu_4
cls
call ghosd.bat
goto quit
:menu_5
cls
call dm.bat
goto quit
:menu_6
cls
call ntfs.bat
goto quit
:menu_7
cls
call menu.bat
goto quit
:cdrom
@ECHO OFF
dready z: /w
if errorlevel 1 goto _errramd
set td=Z:\testdrv.bat
> %td% echo @echo off
>> %td% echo dready %%1
>> %td% echo if errorlevel 1 goto _quit
>> %td% echo set CDOK=%%CDOK%% %%1
>> %td% echo :_quit
LH MSCDEX.EXE /D:mscd001
set CDROM=
findcd /s > nul
SET CDOK=
for %%I in (%cdrom1% %cdrom2% %cdrom3%) DO call %td% %%I
set bootcd=
for %%I in (%cdok%) DO if exist %%I\GHOST\GHOST8.EXE set BOOTCD=%%I
IF %BOOTCD%*==* goto _nobootcd
set CDROM=%bootcd%
echo bootcd=%bootcd%
goto _findbootcdok
:_nobootcd
echo.
echo 错误: 系统没有发现在 CDROM 中有光盘, 请插入配合此条件的光盘!
echo.
echo 在光盘根目录中必须有 GHOST\GHOST.EXE 文件, 否则无法正确找到光盘!
pause
goto _quit
:_findbootcdok
echo.
echo.
echo.
echo 您当前所在的虚拟内存磁盘是在 %RAMD% 盘中!
echo.
echo.
echo 您当前所插入的光盘是在 %CDROM% 盘中!
echo.
echo.
echo 要输入中文文字请按 Alt + F1 区位、Alt + F2 拼音、Alt + F3 五笔、
echo.
echo Alt + F4 双拼来调出输入法,Alt + F5 查看输入法调出,Alt + F10 返回
echo.
goto _quit
:_errramd
echo.
echo 错误:不能在内存磁盘上存取 Q:!
echo.
echo 检查 xmsdsk 是否能建立内存磁盘。
pause
goto _quit
:quit
a:
@echo off
cls
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo 如果你还想继续操作返回主菜单请键入 ZMENU 回车即可!
echo.
set CDROM=
set RAMDRIVE=
:end
:_quit
a:
set CDROM=
set RAMDRIVE=
:end

==================================================================================
以上我们要用到的文件有工具和批处理文件,文件如下:
CHOICE.COM、MSCDEX.EXE、 小工具文件,其它都是批处理文件 7 个 autohf.bat、98se.bat、
doscd.bat、ghosd.bat、dm.bat、ntfs.bat、menu.bat 这 7 个批处理可以这样写只是提供参
考,大家可以修改,因时间有限呀。
① 这是一个全自动的克降文件。
autohf.bat
==================================================================================
[color=#ff0000]
这个全自动 AUTOHF.BAT 文件可按照认识多光驱支持的原理的来是一样的,照红色字复制就行了

==================================================================================
98se.bat 文件,这个是做全自动安装98用的。
==================================================================================
[color=#ff0000]
@echo off
dready z: /w
if errorlevel 1 goto _errramd
set td=Z:\testdrv.bat
> %td% echo @echo off
>> %td% echo dready %%1:
>> %td% echo if errorlevel 1 goto _quit
>> %td% echo set CDOK=%%CDOK%% %%1
>> %td% echo :_quit
LH MSCDEX.EXE /D:mscd001
if not %CDROM%*==* set CDROM=
if not %CDROM%*==* set CDROM=
findcd /s > nul
SET CDOK=
for %%I in (%cdrom1%,%cdrom2%,%cdrom3%) DO call %td% %%I
IF NOT %CDROM%*==* set CDROM=
IF NOT %CDROM%*==* set CDROM=
set bootcd=
for %%I in (%cdok%) DO if exist %%I\setup.exe set BOOTCD=%%I
IF %BOOTCD%*==* goto _nobootcd
set CDROM=%bootcd%
echo bootcd=%bootcd%
goto _findbootcdok
:_nobootcd
echo.
echo.
echo.
echo.
echo 错误: 在光盘根目录下没有发现 WINDOWS 98 SE 的 SETUP.EXE 安装文件 !
echo.
echo 请插入 WINDOWS 98 SE 的安装光盘, 必须在光盘的根目录, 不支持多层目录!
echo.
echo.
echo.
echo.
pause
:_findbootcdok
%CDROM%\setup /is /ie /iv /im /il
zmenu.bat
goto _quit

==================================================================================
doscd.bat 文件,这个是启动到DOS下的文件
==================================================================================
[color=#ff0000]
@echo off
%RAMD%:\
lh ctload VIDE-111.SYS /d:mscd001
LH MSCDEX.EXE /D:mscd001
path=%RAMD%:\;%CDROM%\;a:\
cls
a:

==================================================================================
ghosd.bat 文件,这个是手动克降的GHOST程序
==================================================================================
[color=#ff0000]
E:\tools\ghost -clone,mode=pload,src=E:\tools\xp-sp2.gho:1,dst=1:1,sze1=50p,sze2=50p -fx -ia -sure
zmenu.bat

==================================================================================
dm.bat 文件
==================================================================================
[color=#ff0000]
@echo off
tw /np > nul
dm\dm.com %1 %2 %3 %4 %5%

==================================================================================
ntfs.bat 文件
==================================================================================
[color=#ff0000]
ntfspro.exe > NUL 就这样一句

==================================================================================
menu.bat 文件
==================================================================================
[color=#ff0000]
这是子菜单文件可以按你们的要求来写,我这里不做示范了。

==================================================================================
以上 7 个 菜单文件必须配合相应的工具和软件,必须是无法运行本启动盘的,如 DM 分区软
件、DOS 下的五笔输入法等等,
第三步 再把 NTFS 的程序添加到 IMG 文件中,此程序网上有下载的,名称为 NTFSPRO 5.0
这时因 98 的 IMG 文件只有 1.44 MB 是不够大的,所以要加大这个 IMG 文件,可以用 EASYBOOT
里的工具来完成,详细不说了,如果不会做,可到我的永硕 E 盘中去下载,注意要点是必须把整
个启动盘的文件一个不要少添加,路径千万不要搞错,如我有错处请大家指证。


责任编辑:电脑知识学习网

操作系统